106 lines
3.0 KiB
GDScript
106 lines
3.0 KiB
GDScript
extends Node
|
|
|
|
## NEO-86: prototype HTTP client for [code]GET /game/players/{id}/gig-progression[/code] (NEO-44).
|
|
|
|
signal progression_received(snapshot: Dictionary)
|
|
signal progression_sync_failed(reason: String)
|
|
|
|
const SCHEMA_VERSION := 1
|
|
|
|
@export var base_url: String = "http://127.0.0.1:5253"
|
|
@export var dev_player_id: String = "dev-local-1"
|
|
@export var injected_http: Node = null
|
|
|
|
var _http: Node
|
|
var _busy: bool = false
|
|
|
|
|
|
func _ready() -> void:
|
|
if injected_http != null:
|
|
_http = injected_http
|
|
else:
|
|
_http = HTTPRequest.new()
|
|
add_child(_http)
|
|
if _http is HTTPRequest:
|
|
(_http as HTTPRequest).timeout = 30.0
|
|
@warning_ignore("unsafe_method_access")
|
|
_http.request_completed.connect(_on_request_completed)
|
|
|
|
|
|
func request_sync_from_server() -> void:
|
|
if _busy:
|
|
return
|
|
_busy = true
|
|
var url := "%s/game/players/%s/gig-progression" % [_base_root(), _player_path_segment()]
|
|
var err: Error = _http.request(url)
|
|
if err != OK:
|
|
var reason := "GET failed to start (%s)" % err
|
|
push_warning("GigProgressionClient: %s" % reason)
|
|
_busy = false
|
|
progression_sync_failed.emit(reason)
|
|
|
|
|
|
func gig_row(gig_id: String, snapshot: Dictionary = {}) -> Dictionary:
|
|
var gigs: Variant = snapshot.get("gigs", null)
|
|
if gigs == null or not gigs is Array:
|
|
return {}
|
|
for row_variant in gigs as Array:
|
|
if not row_variant is Dictionary:
|
|
continue
|
|
var row: Dictionary = row_variant
|
|
if str(row.get("id", "")) == gig_id:
|
|
return row
|
|
return {}
|
|
|
|
|
|
func _base_root() -> String:
|
|
return base_url.strip_edges().rstrip("/")
|
|
|
|
|
|
func _player_path_segment() -> String:
|
|
return dev_player_id.strip_edges()
|
|
|
|
|
|
static func parse_progression_json(text: String) -> Variant:
|
|
var parsed: Variant = JSON.parse_string(text)
|
|
if not parsed is Dictionary:
|
|
return null
|
|
var root: Dictionary = parsed
|
|
if int(root.get("schemaVersion", -1)) != SCHEMA_VERSION:
|
|
return null
|
|
var gigs: Variant = root.get("gigs", null)
|
|
if gigs == null or not gigs is Array:
|
|
return null
|
|
if str(root.get("mainGigId", "")).strip_edges().is_empty():
|
|
return null
|
|
return root
|
|
|
|
|
|
func _on_request_completed(
|
|
result: int, response_code: int, _headers: PackedStringArray, body: PackedByteArray
|
|
) -> void:
|
|
_busy = false
|
|
if result != HTTPRequest.RESULT_SUCCESS:
|
|
var reason := "HTTP failed (result=%s)" % result
|
|
push_warning("GigProgressionClient: %s" % reason)
|
|
progression_sync_failed.emit(reason)
|
|
return
|
|
if response_code == 404:
|
|
var reason404 := "HTTP 404 (player unknown)"
|
|
push_warning("GigProgressionClient: %s" % reason404)
|
|
progression_sync_failed.emit(reason404)
|
|
return
|
|
if response_code < 200 or response_code >= 300:
|
|
var reason_code := "HTTP %s" % response_code
|
|
push_warning("GigProgressionClient: %s" % reason_code)
|
|
progression_sync_failed.emit(reason_code)
|
|
return
|
|
var text := body.get_string_from_utf8()
|
|
var snapshot: Variant = parse_progression_json(text)
|
|
if snapshot == null:
|
|
var reason_json := "non-JSON body or schemaVersion mismatch"
|
|
push_warning("GigProgressionClient: %s" % reason_json)
|
|
progression_sync_failed.emit(reason_json)
|
|
return
|
|
progression_received.emit(snapshot as Dictionary)
|